blob: 5a07cbab7b121536acfdf9d78f3c3770426bcf11 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Que Quotion <quequotion@bugmenot.com>
# Contributor David Runge <dvzrv@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
pkgname=alsa-lib-a52pcm
pkgver=1.2.4
pkgrel=1
pkgdesc="An alternative implementation of Linux sound support (with workaround for a52 digital surround PCM)"
arch=('x86_64')
url="https://git.harting.dev/IdleGandalf/alsa-lib/commit/646bc80a63b0220300678a38e0c26a9a13af6fc0"
license=('LGPL2.1')
depends=('glibc' 'alsa-topology-conf' 'alsa-ucm-conf')
provides=('libasound.so' 'libatopology.so' alsa-lib=$pkgver)
conflicts=(alsa-lib=$pkgver)
source=("https://www.alsa-project.org/files/pub/lib/${pkgname%-a52pcm}-$pkgver.tar.bz2"
"pcm-config-parsing-workaround.patch")
sha512sums=('12086952dc8f16f1cb6946517858e17b1c3276aeda9ff5703a84bb38aa78eb4c4e9cb4485c5b3f21f174fdbd976b3bcbbc481e85cb2460652858490df51ae844'
'2de27b4059c3acae13550e9cd2499f51edff48b73a57876d3521619693f343bee817e3d8e29be209c4286131a51164c80ab9823cb2a3fdf1412a2809c94ad7ce')
prepare() {
cd "${pkgname%-a52pcm}-$pkgver"
patch -Np1 < ../pcm-config-parsing-workaround.patch
autoreconf -vfi
}
build() {
cd "${pkgname%-a52pcm}-$pkgver"
./configure --prefix=/usr \
--without-debug
make
}
check() {
cd "${pkgname%-a52pcm}-$pkgver"
export LD_LIBRARY_PATH="${PWD}/src/.libs/:${LD_LIBRARY_PATH}"
make -k check
}
package() {
cd "${pkgname%-a52pcm}-$pkgver"
make DESTDIR="$pkgdir" install
make DESTDIR="$pkgdir" install -C doc
install -vDm 644 {MEMORY-LEAK,TODO,NOTES,ChangeLog,doc/asoundrc.txt} \
-t "${pkgdir}/usr/share/doc/${pkgname}"
}
|