blob: 88b2d63f57a2d916ec09959557b27447325ba515 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
pkgname=alternatives
pkgver=1.15
pkgrel=2
pkgdesc="A tool to maintain symbolic links determining default commands."
arch=('i686' 'x86_64')
url="https://github.com/fedora-sysv/chkconfig"
license=('GPL2')
depends=()
makedepends=()
checkdepends=('beakerlib')
conflicts=('chkconfig' 'dpkg')
source=("https://github.com/fedora-sysv/chkconfig/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('eac2af3e7fc42a3a60b28e04d98dcfbc5c5cb7f51eb02cb71329b6b71ef99d6e')
_srcdir="chkconfig-${pkgver}"
build() {
cd "${_srcdir}"
make alternatives
cd "po"
make
}
check() {
cd "${_srcdir}"
make check
}
package() {
cd "${_srcdir}"
install -dm755 "${pkgdir}/etc/alternatives"
install -Dm755 "alternatives" -t "${pkgdir}/usr/bin/"
ln -s "alternatives" "${pkgdir}/usr/bin/update-alternatives"
install -dm755 "${pkgdir}/var/lib/alternatives"
# Install manual
pushd "po" && make DESTDIR="${pkgdir}" install && popd
install -Dm644 "alternatives.8" -t "${pkgdir}/usr/share/man/man8"
ln -s "alternatives.8" "${pkgdir}/usr/share/man/man8/update-alternatives.8"
install -Dpm644 'COPYING' -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|