blob: 72fca52585501243e431f3fd714bcb303bf86e8f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: CodingKoala <lesy.dimitri+aur@gmail.com>
# Contributor: architekton <architekton350@gmail.com>
pkgname=amass
pkgver=4.1.0
pkgrel=1
pkgdesc="In-depth Attack Surface Mapping and Asset Discovery"
arch=('any')
url="https://github.com/OWASP/Amass"
license=('Apache')
makedepends=('go' 'git')
source=(Amass-$pkgver.tar.gz::https://github.com/OWASP/Amass/archive/v${pkgver}.tar.gz)
sha512sums=('e5b56b78d2c88aa0836d5bf3b77aa8e5d9a9c3c9f7fbacda33e911343913faffaf54abb596a65495bdd5efbadb95c38a892857dc4b5a3c7981f4ba8f0b6a0ed1')
build() {
cd "amass-$pkgver"
mkdir bin
go build \
-trimpath \
-ldflags "-extldflags $LDFLAGS" \
-v -o bin/ ./cmd/...
}
check() {
cd "amass-$pkgver"
go test ./...
# Remove golang mod cache otherwise makepkg clean doesn't work due to perms
go clean -modcache
}
package() {
cd "amass-$pkgver"
install -dm 755 "${pkgdir}/usr/share/${pkgname}"
install -Dm 755 "bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
cp -a --no-preserve=ownership "examples/" "${pkgdir}/usr/share/${pkgname}"
find "${pkgdir}/usr/share/${pkgname}/examples" -type d -exec chmod 755 {} \;
find "${pkgdir}/usr/share/${pkgname}/examples" -type f -exec chmod 644 {} \;
}
|