summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3cd76cc2b0cf492434cd425bbae049e7e1d77eee (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=amide-hg
pkgver=1.0.6r109.7b8fc8a59fd2
pkgrel=8
pkgdesc="Medical Imaging Data Examiner - mercurial checkout"
url="http://amide.sourceforge.net/packages.html"
arch=('i686' 'x86_64')
license=('GPL')
depends=('dcmtk' 'xmedcon' 'libgnomecanvas' 'gnome-vfs' 'ffmpeg' 'gsl' 'volpack')
makedepends=('gnome-doc-utils' 'gtk-doc' 'intltool' 'mercurial')
conflicts=('amide')
provides=('amide')
source=(amide::hg+http://hg.code.sf.net/p/amide/code)
md5sums=('SKIP')
options=('!makeflags')

pkgver() {
  cd ${pkgname%-hg}/${pkgname%-hg}-current
  printf "1.0.6r%s.%s" "$(hg identify -n| tr -d +)" "$(hg identify -i| tr -d +)"
}

prepare() {
  cd ${pkgname%-hg}/${pkgname%-hg}-current
  sed -i "s+aclocal-1.14+aclocal-1.15+" Makefile.am
  sed -i "s+automake-1.14+automake-1.15+" Makefile.am
}

build() {
  cd ${pkgname%-hg}/${pkgname%-hg}-current
  autoreconf
  ./configure --prefix=/usr --enable-ffmpeg --enable-libvolpack \
	      --enable-libdcmdata --with-xmedcon-exec-prefix=/usr/bin
  make
}

package() {
  cd ${pkgname%-hg}/${pkgname%-hg}-current
  make DESTDIR="$pkgdir" install
  sed -i 's+.png++' "$pkgdir"/usr/share/applications/amide.desktop
}