summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 149a20ed1d7493e6eaf2901ddb6695e7441cc808 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
# Maintainer: TJM <tommy.mairo@gmail.com>
# Contributor: Yijian Chen <dastudiodirector@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Henrik Ronellenfitsch <searinox@web.de>
# Contributor: Alessio Sergi <sergi.alessio {at} gmail.com>
# Contributor: Dario 'Dax' Vilardi <dax [at] deelab [dot] org>
# Contributor: Anatol Pomozov <anatol.pomozov@gmail.com>
pkgname=amule-dlp-git
pkgver=2.3.2.r10468.3e9f92bc3
pkgrel=1
pkgdesc="An eMule-like client for ed2k p2p network with DLP patch"
arch=('i686' 'x86_64')
url="https://github.com/persmule/amule-dlp"
license=('GPL')
depends=('wxgtk' 'gd' 'geoip' 'libupnp' 'crypto++>=6.0.0' 'libsm' 'boost-libs')
conflicts=('amule' 'amule-dlp' 'amule-dlp-hg')
makedepends=('git' 'boost')
optdepends=('antileech')
install=amule.install
provides=('amule' 'amule-dlp')
source=("git+https://github.com/persmule/amule-dlp.git#commit=3e9f92bc350036fe8d4958247b6d99d34a513492"
        'amuled.systemd'
		'amuleweb.systemd')
sha256sums=('SKIP'
            '6dbdd1ad1c3c3d8637b8f4cbd5416f39c8e4277a2f8498577b08bf6cda8dbca9'
			'f4f43b1154ddccc9036a4291a58c6715f097b171fec62ea7aead0c9d9fa654f2')

pkgver() {
  cd "${srcdir}/amule-dlp"
  printf "2.3.2.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare(){
  cd "${srcdir}/amule-dlp"
  cp src/aMule.xpm amule.xpm
}

build() {
  cd "${srcdir}/amule-dlp"

  ./autogen.sh
  ./configure \
	  --prefix=/usr \
	  --mandir=/usr/share/man \
	  --disable-debug \
	  --enable-amule-daemon \
	  --enable-amulecmd \
	  --enable-amule-gui \
	  --enable-webserver \
	  --enable-cas \
	  --enable-wxcas \
	  --enable-alc \
	  --enable-alcc \
	  --enable-geoip \
	  --enable-upnp \
	  --with-denoise-level=3 \
	  --enable-nls \
	  --enable-optimize \
	  --enable-mmap \
	  --enable-ccache \
	  --with-boost \
	  --with-wxversion=3.0

  make 
}

package() {
  cd "${srcdir}/amule-dlp"

  make DESTDIR=${pkgdir} install

  install -D -m644 "${srcdir}/amuled.systemd" "${pkgdir}/usr/lib/systemd/system/amuled.service"
  install -D -m644 "${srcdir}/amuleweb.systemd" "${pkgdir}/usr/lib/systemd/system/amuleweb.service"
}