PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: Campbell Jones <serebit at archlinux dot org>
# Contributor: Sandy Carter <aur at sandy dot mozmail dot com>
# Contributor: JstKddng <jk at vin dot ovh>

_android_arch=aarch64

pkgname=android-${_android_arch}-argparse
pkgver=3.1
pkgrel=1
arch=('any')
pkgdesc="Argument Parser for Modern C++ (Android ${_android_arch})"
url="https://github.com/p-ranav/argparse"
license=('MIT')
groups=('android-argparse')
depends=('android-ndk')
makedepends=('android-cmake')
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://github.com/p-ranav/argparse/archive/v${pkgver}.tar.gz")
md5sums=('11822ccbe1bd8d84c948450d24281b67')

build() {
    cd "${srcdir}/argparse-${pkgver}"
    source android-env ${_android_arch}

    android-${_android_arch}-cmake \
        -S . \
        -B build \
        -DARGPARSE_BUILD_SAMPLES=OFF \
        -DARGPARSE_BUILD_TESTS=OFF \
        -Wno-dev
    make -C build $MAKEFLAGS
}

package() {
    cd "${srcdir}/argparse-${pkgver}"
    source android-env ${_android_arch}

    make -C build DESTDIR="${pkgdir}" install
}