PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# PKGBUILD for android-giflib
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>

_android_arch=aarch64
source android-env.sh ${_android_arch}

pkgname=android-${_android_arch}-giflib
pkgver=5.1.9
pkgrel=1
pkgdesc="A library for reading and writing gif images (android)"
arch=('any')
url="http://sourceforge.net/projects/giflib/"
license=("MIT")
depends=('android-ndk')
options=(!strip !buildflags staticlibs !emptydirs)
makedepends=('android-pkg-config')
source=("http://downloads.sourceforge.net/sourceforge/giflib/giflib-${pkgver}.tar.bz2"
        'Makefile.patch')
md5sums=('c1df79d223b10b92f44ca649ef5f1459'
         '0c6a08273d51f7fd965c79c967f5e7ed')

prepare() {
    cd "${srcdir}"/giflib-${pkgver}

    check_ndk_version_ge_than 18.0
    patch -Np1 -i "../Makefile.patch"
}

build() {
    cd "${srcdir}"/giflib-${pkgver}

    make \
        libgif.a \
        libgif.so \
        CC=${ANDROID_CC} \
        AR=${ANDROID_AR} \
        $MAKEFLAGS
}

package() {
    cd "${srcdir}"/giflib-${pkgver}

    make DESTDIR="$pkgdir" install-include install-lib
    mkdir -p "${pkgdir}"/${ANDROID_LIBS}
    mv -vf "${pkgdir}"/usr/local/* "${pkgdir}"/${ANDROID_LIBS}/
    ${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}"/${ANDROID_LIBS}/lib/*.so
    ${ANDROID_STRIP} -g "$pkgdir"/${ANDROID_LIBS}/lib/*.a
}