summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fa45739ca5adb796fe29e2438f7a5ab6ac1e196f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: drakkan <nicola.murino at gmail dot com>

_android_arch=aarch64

pkgname=android-${_android_arch}-libnghttp2
pkgver=1.62.0
pkgrel=1
arch=('any')
pkgdesc="Framing layer of HTTP/2 is implemented as a reusable C library (Android ${_android_arch})"
url='https://nghttp2.org/'
license=('MIT')
depends=('android-ndk')
makedepends=('android-configure')
options=(!strip !buildflags staticlibs !emptydirs)
source=("https://github.com/nghttp2/nghttp2/releases/download/v${pkgver}/nghttp2-${pkgver}.tar.xz")
md5sums=('2338109299e1d83a1191509baa6daacb')

build() {
    cd "${srcdir}/nghttp2-$pkgver"
    source android-env ${_android_arch}

    android-${_android_arch}-configure \
        --disable-examples \
        --enable-lib-only
    make $MAKEFLAGS
}

package() {
    cd "${srcdir}/nghttp2-$pkgver"
    source android-env ${_android_arch}

    make DESTDIR="$pkgdir" install
    rm -rf "${pkgdir}/${ANDROID_PREFIX_SHARE}/doc"
    rm -rf "${pkgdir}/${ANDROID_PREFIX_SHARE}/man"
    ${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.so
    ${ANDROID_STRIP} -g "${pkgdir}/${ANDROID_PREFIX_LIB}"/*.a
}