PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Zhang Hai <dreaming.in.code.zh@gmail.com>

# Taken from android-sdk

pkgname=android-sdk-dummy
_pkgname=android-sdk
pkgver=25.1.6
pkgrel=2
pkgdesc='Google Android SDK, dummy package'
arch=('i686' 'x86_64')
url='http://developer.android.com/sdk/'
license=('custom')
depends_i686=('java-environment' 'alsa-lib' 'openal' 'libstdc++5' 'libxv' 'sdl' 'ncurses' 'swt'
              'zlib' 'ncurses5-compat-libs')
depends_x86_64=('java-environment' 'lib32-alsa-lib' 'lib32-openal' 'lib32-libstdc++5' 'lib32-libxv'
                'lib32-mesa' 'lib32-ncurses' 'lib32-sdl' 'lib32-zlib' 'lib32-fontconfig'
                'lib32-libpulse' 'swt' 'ncurses5-compat-libs')
optdepends=('android-udev: udev rules for Android devices'
            'android-sdk-platform-tools: adb, aapt, aidl, dexdump and dx')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
install="${pkgname}.install"
source=("${_pkgname}.png"
        "${_pkgname}.desktop::https://aur.archlinux.org/cgit/aur.git/plain/${_pkgname}.desktop?h=${_pkgname}"
        "${_pkgname}.sh::https://aur.archlinux.org/cgit/aur.git/plain/${_pkgname}.sh?h=${_pkgname}"
        "${_pkgname}.csh::https://aur.archlinux.org/cgit/aur.git/plain/${_pkgname}.csh?h=${_pkgname}"
        "${_pkgname}.conf::https://aur.archlinux.org/cgit/aur.git/plain/${_pkgname}.conf?h=${_pkgname}"
        "license.html::https://aur.archlinux.org/cgit/aur.git/plain/license.html?h=${_pkgname}")
sha1sums=('429cfcb7c161e5fd60c9f155a6436ba5c78f7af7'
          '8f886de363ad91a7f93a0c6ded993e99bef3e1a7'
          '78f8574e651c9bf8b7515ecb30c7ef93edbc4a96'
          '08c85aab7523e22b298891c7047bc0e7adbf3437'
          '145bdf3eb41a56574b289c1577a24bc47097ec83'
          'bfb91be7e0b602d765b7a1fcaf0ce1b7e1a93faa')

package() {
  install -Dm755 "${_pkgname}.sh" "${pkgdir}/etc/profile.d/${_pkgname}.sh"
  install -Dm755 "${_pkgname}.csh" "${pkgdir}/etc/profile.d/${_pkgname}.csh"
  install -Dm644 "${_pkgname}.conf" "${pkgdir}/etc/ld.so.conf.d/${_pkgname}.conf"
  install -Dm644 "${_pkgname}.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
  install -Dm644 "${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
  install -Dm644 license.html "${pkgdir}/usr/share/licenses/${_pkgname}/license.html"
}