summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1616fabee0bf67723d8a9b4b0d0be1bec4806735 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>
# Contributor: pingplug < aur at pingplug dot me >
# Contributor: Schala Zeal < schalaalexiazeal at gmail dot com >
# Contributor: bubla < matej dot tyc at gmail dot com >

_android_arch=x86-64

pkgname=android-${_android_arch}-libtiff
pkgver=4.1.0
pkgrel=1
pkgdesc="Library for manipulation of TIFF images (android)"
arch=('any')
url="http://www.simplesystems.org/libtiff/"
license=('custom')
depends=("android-${_android_arch}-libjpeg-turbo"
         "android-${_android_arch}-zlib"
         "android-${_android_arch}-xz")
options=(!strip !buildflags staticlibs !emptydirs)
makedepends=('android-configure')
source=("http://download.osgeo.org/libtiff/tiff-${pkgver}.tar.gz")
sha256sums=('5d29f32517dadb6dbcd1255ea5bbc93a2b54b94fbf83653b4d65c7d6775b8634')

build() {
    cd "${srcdir}/tiff-${pkgver}"
    source android-env ${_android_arch}
    export CFLAGS="-fno-strict-aliasing"
    export CXXFLAGS="-fno-strict-aliasing"

    android-${_android_arch}-configure \
        --disable-jbig \
        --without-x

    make $MAKEFLAGS
}

package() {
    cd "${srcdir}/tiff-${pkgver}"
    source android-env ${_android_arch}

    make DESTDIR="$pkgdir" install
    cp libtiff/{tiffiop,tif_dir}.h "${pkgdir}/${ANDROID_PREFIX_INCLUDE}/"
    cp libtiff/tif_config.h "${pkgdir}/${ANDROID_PREFIX_INCLUDE}/"
    rm -r "${pkgdir}"/${ANDROID_PREFIX_BIN}
    rm -r "${pkgdir}"/${ANDROID_PREFIX_SHARE}
    ${ANDROID_STRIP} -g --strip-unneeded "${pkgdir}"/${ANDROID_PREFIX_LIB}/*.so
    ${ANDROID_STRIP} -g "$pkgdir"/${ANDROID_PREFIX_LIB}/*.a
}