PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

# Maintainer: txtsd <aur.archlinux@ihavea.quest>

pkgname=android_translation_layer-git
_pkgname=${pkgname%%-git}
_pkgname=${_pkgname//-/_}
pkgver=r637.3d02598
pkgrel=1
pkgdesc='A translation layer for running Android apps on a Linux system'
url='https://gitlab.com/android_translation_layer/android_translation_layer'
arch=('x86_64' 'aarch64' 'armv7h')
license=('GPL-3.0-or-later')
# libopensles-standalone is not strictly required but some Android applications depend on it
depends=(
  alsa-lib
  art_standalone
  bionic_translation
  ffmpeg
  gdk-pixbuf2
  glib2
  glibc
  graphene
  gtk4
  java-runtime
  libglvnd
  libgudev
  libopensles-standalone
  libportal
  pango
  skia-sharp
  sqlite
  vulkan-icd-loader
  webkitgtk-6.0
)
makedepends=(
  git
  glib2-devel
  java-runtime-common
  jdk8-openjdk
  meson
  openxr
  vulkan-headers
  wayland-protocols
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd ${_pkgname}
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  meson subprojects download --sourcedir=${_pkgname}
}

build() {
  arch-meson ${_pkgname} build
	meson compile -C build
}

check() {
	meson test --no-rebuild --print-errorlogs -C build
}

package() {
	meson install --no-rebuild -C build --destdir "${pkgdir}"
}