blob: 9733012ba794c61a8f08d19335540a09f3527125 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
_pkgname='anew'
pkgname="${_pkgname}-git"
pkgver=r6.f212493
pkgrel=1
pkgdesc='Append lines from stdin to a file, but only if they dont already appear in the file'
arch=('x86_64')
url='https://github.com/tomnomnom/anew'
license=('MIT')
makedepends=('git' 'go')
provides=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')
prepare() {
export GOPATH="${srcdir}/gopath"
go clean -modcache
}
pkgver() {
cd "${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${_pkgname}"
go build -v -o "${_pkgname}" main.go
}
package() {
cd "${_pkgname}"
install -Dm755 -t "${pkgdir}/usr/bin" "${_pkgname}"
install -Dm644 -t "${pkgdir}/usr/share/doc/${_pkgname}" 'README.mkd'
install -Dm644 -t "${pkgdir}/usr/share/licenses/${_pkgname}" 'LICENSE'
}
# vim: ts=2 sw=2 et:
|