blob: cfeee55bb96c77b751b8ef6cf934303ca25dceb5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: k1f0 <archlinux at k1f0.mozmail.com>
pkgname=angryoxide
_pkgname=AngryOxide
pkgver=0.8.8
pkgrel=1
_patch=""
pkgdesc='802.11 Attack Tool'
arch=('x86_64')
url='https://github.com/Ragnt/AngryOxide'
license=('GPL-3.0-only')
makedepends=('cargo' 'git')
options=(!lto)
source=("${pkgname}-${pkgver}${_patch}::${url}/archive/refs/tags/v${pkgver}${_patch}.tar.gz")
b2sums=('ff649b3e656814caf99904091ee7d06d880b041fa2f7f1893732d153c2b21fec13d6df388ed2d1fb25658d47b4cc11791ff57a5d77bd8c8458696c21211fd423')
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}${_patch}"
cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}${_patch}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}${_patch}"
# executable
install -Dm0755 -t "${pkgdir}/usr/bin" "target/release/${pkgname}"
# bash completion
mv completions/bash_angryoxide_completions completions/angryoxide
install -Dm0644 -t "${pkgdir}/usr/share/bash-completion/completions" "completions/${pkgname}"
# zsh completion
mv completions/zsh_angryoxide_completions completions/_angryoxide
install -Dm0644 -t "${pkgdir}/usr/share/zsh/site-functions" "completions/_${pkgname}"
}
|