PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: jullanggit <jullanggit@proton.me>
_pkgname=anymex
_PkgName=AnymeX
pkgname=${_pkgname}-bin
pkgver=3.0.4
pkgrel=1
arch=(x86_64)
pkgdesc='An Open Source app for Tracking Multi Service (AL, MAL, SIMKL)'
url="https://github.com/RyanYuuki/${_PkgName}"
license=(MIT)
provides=(${_pkgname}=${pkgver})
depends=('libepoxy' 'gdk-pixbuf2' 'pango' 'webkit2gtk-4.1' 'harfbuzz' 'libsoup3' 'glibc' 'fontconfig' 'cairo' 'hicolor-icon-theme' 'glib2' 'gcc-libs' 'mpv' 'zlib-ng-compat' 'gtk3' 'at-spi2-core')
conflicts=(anymex)
_appimage="${_PkgName}-${pkgver}.AppImage"
source=("${_appimage}::${url}/releases/download/v3.0.4/${_PkgName}-Linux.AppImage"
        "LICENSE-${pkgver}.md::https://raw.githubusercontent.com/RyanYuuki/AnymeX/refs/tags/v3.0.4/LICENSE.md")
noextract=(${_appimage})
sha256sums=('e588841bc3276f9b1e9c6312df8e22b8a56a2feaf5353974ee97c5f74c86802c' 'SKIP')

prepare() {
    chmod +x "${_appimage}"
    ./"${_appimage}" --appimage-extract >/dev/null
}

build() {
    chmod -R a-x+rX squashfs-root/usr
    chmod +x squashfs-root/usr/bin/anymex
}

package() {
    install -dm755 "${pkgdir}/usr/"
    mv "${srcdir}"/squashfs-root/usr/* "${pkgdir}/usr/"
    install -Dm644 "${srcdir}/LICENSE-${pkgver}.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
    install -Dm644 /dev/stdin "${pkgdir}/usr/share/applications/${_pkgname}.desktop" <<DESKTOP
[Desktop Entry]
Version=${pkgver}
Type=Application
Name=${_PkgName}
GenericName=${_PkgName}
Comment=${pkgdesc}
Exec=${_pkgname}
Icon=${_pkgname}
Terminal=false
Categories=Utility;Application;
Keywords=${_pkgname};anime
StartupNotify=true
DESKTOP
}