PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Yen Chi Hsuan <yan12125@gmail.com>
# Contributor: Michał Górny <zrchos+arch@gmail.com>
# Contributor: Ryan Lee <ryan@swyro.com>

pkgname=apache-flex-sdk
pkgver=4.16.1
_player_ver=27.0
pkgrel=1
pkgdesc="The open-source framework for building expressive web and mobile applications"
arch=('any')
license=('Apache')
url='https://flex.apache.org/'
depends=('bash' 'java-runtime')
optdepends=(
    'adobe-air-sdk: for compiling flex projects into AIR apps'
)
source=(
    "https://www.apache.org/dist/flex/$pkgver/binaries/apache-flex-sdk-$pkgver-bin.tar.gz"{,.asc}
    "https://fpdownload.macromedia.com/get/flashplayer/updaters/${_player_ver%%.*}/playerglobal${_player_ver/./_}.swc"
    "apache-flex-sdk.sh"
)
sha256sums=('17fda7ac8d3e476cad3127f345455ef316acfb87c6f4322e5897bd8d9b09388e'
            'SKIP'
            '4e4cbe1a936a25c405f988293033b50a31a00f23ed6e2401ba5563a4e95b8263'
            '520ae01482825ef28da42c03b3cbadd3d62155ed074d737f3672980f0a97a3fd')
# Check https://www.apache.org/dist/flex/KEYS for whether a key is really from an Apache developer or not
validpgpkeys=(
    'E28487967B092453A2AB8DA9E0F28593AEEAD151'  # Justin Mclean
    '44998F3E242727E94C4BADEB6B0A7EC905061FC8'  # Piotr Zarzycki
)
install=apache-flex-sdk.install
options=('!strip')
noextract=('playerglobal11_1.swc')

_binary_name="${pkgname}-${pkgver}-bin.tar.gz"

build() {
    cd "${srcdir}/${pkgname}-${pkgver}-bin/"
    mkdir -p player/${_player_ver}/
    cp ../playerglobal${_player_ver/./_}.swc player/${_player_ver}/playerglobal.swc
}

package() {
    cd "${srcdir}"
    install -dDm755 "${pkgdir}/opt"
    cp -dr --no-preserve=ownership ${pkgname}-${pkgver}-bin "${pkgdir}/opt/${pkgname}"
    rm "${pkgdir}/opt/${pkgname}/bin/"*.bat
    install -Dm755 apache-flex-sdk.sh "${pkgdir}/etc/profile.d/apache-flex-sdk.sh"
}