blob: 444d234400a14256280d82548bf640d5ab67c55d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=apostrophe
pkgver=2.6.3
pkgrel=6
pkgdesc="A distraction free Markdown editor for GNU/Linux made with GTK+"
arch=('any')
url="https://world.pages.gitlab.gnome.org/apostrophe"
license=('GPL-3.0-or-later')
depends=(
'gspell'
'libhandy'
'otf-fira-mono'
'otf-fira-sans'
'python-cairo'
'python-chardet'
'python-gobject'
'python-levenshtein'
'python-pyenchant'
'python-pypandoc'
'python-regex'
'python-setuptools'
'webkit2gtk-4.1'
)
makedepends=(
'gobject-introspection'
'meson'
'sassc'
)
checkdepends=('appstream-glib')
optdepends=(
'mathjax: for formula preview'
'texlive-bin: for the pdftex module'
)
source=("https://gitlab.gnome.org/World/apostrophe/-/archive/v$pkgver/$pkgname-v$pkgver.tar.gz"
'Allow-building-with-webkitgtk-4.1.patch')
sha256sums=('6f73c80146af0820ec705ec8b32ec64f0f323f51de6b6a4cfd4d02f0719876f3'
'c5c64aa312a17fcf761b0da956147f91532c8c43b33d608ca3acb6f10bd53d12')
prepare() {
cd "$pkgname-v$pkgver"
# Bug 1953395 - Apostrophe can't export to HTML
sed -i 's|/app/share/fonts/FiraSans-Regular.ttf|/usr/share/fonts/OTF/FiraSans-Regular.otf|' \
data/media/css/web/base.css
sed -i 's|/app/share/fonts/FiraMono-Regular.ttf|/usr/share/fonts/OTF/FiraMono-Regular.otf|' \
data/media/css/web/base.css
# W: hidden-file-or-dir
rm apostrophe/.pylintrc
patch -Np1 -i ../Allow-building-with-webkitgtk-4.1.patch
}
build() {
arch-meson "$pkgname-v$pkgver" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|