blob: 97c5a589cc8a410474d592a43a69a7bb40799cf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: MithicSpirit <rpc01234 at gmail dot com>
_pkgname=appflowy
pkgname=$_pkgname-git
pkgver=latest
pkgrel=5
pkgdesc='An open-source alternative to Notion.'
arch=(x86_64)
url='https://www.appflowy.io/'
license=('AGPL3')
depends=('glibc>=2.32' gtk3)
makedepends=(git clang cmake ninja unzip rust cargo dart sqlite)
provides=($_pkgname)
conflicts=($_pkgname $_pkgname-bin)
replaces=()
backup=()
options=()
install=
source=(
"$_pkgname::git+https://github.com/AppFlowy-IO/AppFlowy.git"
'flutter::git+https://github.com/flutter/flutter.git'
)
sha256sums=('SKIP' 'SKIP')
_setpath() {
PATH="$PATH:$srcdir/flutter/bin:$HOME/.pub-cache/bin:$HOME/.cargo/bin"
}
pkgver() {
_setpath
cd "$srcdir/$_pkgname"
git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
}
prepare() {
_setpath
flutter channel stable
flutter config --enable-linux-desktop
cd "$srcdir/$_pkgname/frontend"
sed -i "/rustup/d" scripts/makefile/env.toml
}
build() {
_setpath
cargo install cargo-make
cargo install duckscript_cli
cd "$srcdir/$_pkgname/frontend"
cargo make flowy_dev
cargo make --profile production-linux-x86_64 appflowy
}
package() {
_setpath
cd "$srcdir/$_pkgname/frontend/app_flowy/product/"*/linux/Release/AppFlowy
install -dm755 "$pkgdir"{/usr/bin,/usr/share/applications,"/opt/$pkgname"}
cp -a * "$pkgdir/opt/$pkgname/"
rm "$pkgdir/opt/$pkgname/appflowy.desktop.temp"
ln -s "/opt/$pkgname/app_flowy" "$pkgdir/usr/bin/"
_desktop_file="$pkgdir/usr/share/applications/AppFlowy.desktop"
install -m644 appflowy.desktop.temp "$_desktop_file"
sed -i '/Exec=/s|\[CHANGE_THIS\]/AppFlowy|/usr/bin|' "$_desktop_file"
sed -i "/Icon=/s|\[CHANGE_THIS\]/AppFlowy|/opt/$pkgname|" "$_desktop_file"
}
|