blob: 787df11b7bda3e9a629ce5d77bb846db62ff7dc5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Fredy García <frealgagu at gmail dot com>
# Contributor: Pawel Mosakowski <pawel at mosakowski dot net>
pkgname=appgate-sdp-headless
pkgver=5.5.2
pkgrel=1
pkgdesc="Appgate SDP (Software Defined Perimeter) headless client (It does not support 2FA.)"
arch=("x86_64")
url="https://www.${pkgname%%-*}.com/support/software-defined-perimeter-support"
license=("custom" "custom:commercial")
depends=("dnsmasq" "libsecret" "libxss" "nodejs" "nss" "python-dbus" "python-distro")
optdepends=("bash-completion: allows bash completion for scripts")
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
backup=("etc/appgate.conf" "etc/dbus-1/system.d/appgate.conf")
options=(staticlibs !strip !emptydirs)
source=(
"https://bin.${pkgname%-*}.com/${pkgver%.*}/client/${pkgname}_${pkgver}_amd64.deb"
"${pkgname%%-*}driver.service.patch"
)
sha256sums=(
"fa4ea0aa6c14460e8e711a52be7738a40af6fcb20b3b1c47d6c65a90b9f9ec64"
"0789aa07d6a7af44187e407696d930e78c50370c19b8399722ebecb0655ffcdb"
)
prepare() {
mkdir "${srcdir}/${pkgname}"
cd "${srcdir}/${pkgname}"
bsdtar -xf "${srcdir}/data.tar.xz" -C .
patch -Np1 -i "${srcdir}/${pkgname%%-*}driver.service.patch"
# Remove unnecessary .deb related directory
rm -rf "${srcdir}/${pkgname}/etc/init.d"
}
package() {
# Install application files
cp -dpr "${srcdir}/${pkgname}/"{etc,opt,usr} "${pkgdir}"
# Install service files
install -dm755 "${pkgdir}/usr/lib/systemd/system"
install -Dm644 "${srcdir}/${pkgname}/lib/systemd/system/"* "${pkgdir}/usr/lib/systemd/system/"
mv "${pkgdir}/usr/sbin" "${pkgdir}/usr/bin"
# Install license files
install -Dm644 "${srcdir}/${pkgname}/usr/share/doc/${pkgname/-sdp/}/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
}
|