PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: James Kittsmiller (AJSlye) <james@nulogicsystems.com>
# Contributor: TheAssassin

pkgname=appimagelauncher-git
pkgver=r1068.7cb4d70
pkgrel=1
pkgdesc="A Helper application for running and integrating AppImages."
arch=(x86_64)
url="https://github.com/TheAssassin/AppImageLauncher"
license=(MIT)
depends=(qt5-base fuse2 squashfuse libappimage)
makedepends=(git cmake boost qt5-tools)
provides=(appimagelauncher)
conflicts=(appimagelauncher)
source=("${pkgname%-git}::git+https://github.com/TheAssassin/AppImageLauncher.git"
        "git+https://github.com/AppImage/AppImageUpdate.git"
        "git+https://github.com/AppImage/libappimage.git"
        "git+https://github.com/TheAssassin/zsync2.git"
        "git+https://github.com/TheAssassin/fltk-1.3.4.git"
        "git+https://github.com/TheAssassin/libdesktopenvironments.git"
        "git+https://github.com/arsenm/sanitizers-cmake.git"
        "git+https://github.com/google/googletest.git"
        "git+https://github.com/AppImage/cpr.git"
        "git+https://github.com/Taywee/args.git"
        'appimage-binfmt-remove.hook')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            '72a2630cf79b8f90bc21eae1d9f40c07fe77ce22df46c511b500f514455d7c81')

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
#  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/${pkgname%-git}"

  git submodule init
  git config submodule.lib/AppImageUpdate.url "${srcdir}/AppImageUpdate"
  git config submodule.lib/libappimage.url "${srcdir}/libappimage"
  git submodule update 

  cd "$srcdir/${pkgname%-git}/lib/AppImageUpdate"
  git submodule init
  git config submodule.lib/zsync2.url "${srcdir}/zsync2"
  git config submodule.lib/fltk.url "${srcdir}/fltk-1.3.4"
  git config submodule.lib/libdesktopenvironments.url  "${srcdir}/libdesktopenvironments"
  git config submodule.lib/sanitizers-cmake.url "${srcdir}/sanitizers-cmake"
  git config submodule.lib/libappimage.url "${srcdir}/libappimage"
  git submodule update

  cd "$srcdir/${pkgname%-git}/lib/AppImageUpdate/lib/libappimage"
  git submodule init
  git config submodule.lib/gtest.url "${srcdir}/googletest"
  git submodule update

  cd "$srcdir/${pkgname%-git}/lib/AppImageUpdate/lib/zsync2"
  git submodule init
  git config submodule.lib/cpr.url "${srcdir}/cpr"
  git config submodule.lib/args.url "${srcdir}/args"
  git config submodule.lib/gtest.url "${srcdir}/googletest"
  git submodule update

  cd "${srcdir}/${pkgname%-git}/lib/libappimage"
  git submodule init
  git config submodule.lib/gtest.url "${srcdir}/googletest"
  git submodule update
}

build() {
  cd "$srcdir/${pkgname%-git}"

  cmake . \
        -DCMAKE_INSTALL_PREFIX=/usr/ \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DUSE_SYSTEM_LIBAPPIMAGE=ON \
        -DBUILD_TESTING=OFF
  make libappimageupdate libappimageupdate-qt
  cmake .
  make
}

package() {
  cd "$srcdir/${pkgname%-git}"
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 ../appimage-binfmt-remove.hook "$pkgdir"/usr/share/libalpm/hooks/appimage-binfmt-remove.hook
}