blob: ed19ed6405e2c0b08a025219815574604004a634 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Christian Hesse <arch@eworm.de>
# Contributor: speps <speps at aur dot archlinux dot org>
pkgname=apulse
pkgver=0.1.13
pkgrel=1
pkgdesc='PulseAudio emulation for ALSA'
arch=('i686' 'x86_64')
url='https://github.com/i-rinat/apulse'
license=('custom:MIT')
depends=('alsa-lib' 'glib2')
makedepends=('cmake')
install=apulse.install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
'asoundrc.sample')
sha256sums=('9234ec4e10e408b9c01d5f4ea768ad1fc15494217c932db2c435202a9c7b5efd'
'e851197ec9ebff528154210751cd6d5c426abfc2b1aa34343580407b1ea789a4')
prepare() {
cd apulse-${pkgver}
mkdir -p build
}
build() {
cd apulse-${pkgver}/build
cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release
make
}
package() {
cd apulse-${pkgver}/build
make DESTDIR="${pkgdir}/" install
# sample asoundrc
install -Dm644 ../../${source[1]} \
"${pkgdir}/usr/share/${pkgname}/${source[1]}"
# license
install -Dm644 ../LICENSE.MIT \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|