blob: b819039b2de36917cb359249cc855786c24e42b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: tarball <bootctl@gmail.com>
# Contributor: Philip Goto <philip.goto@gmail.com>
# Contributor: fortea
pkgname=apx
pkgver=2.4.0
pkgrel=1
pkgdesc='Package manager with support for multiple sources'
arch=(x86_64 aarch64)
url='https://github.com/Vanilla-OS/apx'
license=(GPL-3.0-only)
depends=(
distrobox
glibc
)
makedepends=(go)
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
b2sums=('0ff60546fcce40c808d3aa8c27faebf2c1c0d29c8b7ee2534ec2fde93f5d2bc5c9f5c33a61eafea2c931f4195585209307e853ce722ea2a4636ced9680adb11a')
prepare() {
cd "${pkgname}-${pkgver}"
mkdir -p build/
sed -i 's|share/apx|bin|' config/apx.json
sed -i 's|bin/distrobox|bin|' config/apx.json
}
build() {
cd "${pkgname}-${pkgver}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o build
for shell in bash fish zsh; do
./build/apx completion $shell >build/$pkgname.$shell
done
}
package() {
cd "${pkgname}-${pkgver}"
# binary
install -Dm755 "build/$pkgname" "$pkgdir/usr/bin/$pkgname"
# config
install -Dm644 "config/apx.json" "$pkgdir/etc/apx/apx.json"
# man pages
install -Dm644 man/man1/apx.1 "$pkgdir/usr/share/man/man1/apx.1"
# completions
install -Dm644 build/$pkgname.bash "$pkgdir/usr/share/bash-completion/completions/$pkgname"
install -Dm644 build/$pkgname.fish "$pkgdir/usr/share/fish/vendor_completions.d/$pkgname.fish"
install -Dm644 build/$pkgname.zsh "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
}
|