summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1759d7fec517edae06bab8e51e0f72f3415fb66b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Maintainer: Doug Newgard <scimmia at archlinux dot info>
# Contributor: Sergio Correia <sergio@correia.cc>
# Contributor: Nicolas Vivet <nizzox@gmail.com>

_pkgname=arcanist
pkgname=$_pkgname-git
pkgver=6.r828.g9ddf37b
pkgrel=1
pkgdesc='The command-line frontend to Phabricator, commonly called arc'
arch=('any')
url="http://phabricator.com"
license=('Apache')
depends=('libphutil-git' 'python')
makedepends=('git')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("git://github.com/facebook/$_pkgname.git")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags --always | sed 's/^conduit-//;s/-/.r/;s/-/./'
}

package() {
  install -d "$pkgdir/usr/share/php/$_pkgname" "$pkgdir/usr/bin"
# do not copy hidden directories
  cp -a $_pkgname/* "$pkgdir/usr/share/php/$_pkgname/"
  install -Dm644 $_pkgname/resources/shell/bash-completion "$pkgdir/usr/share/bash-completion/completions/arc"
  ln -s ../share/php/$_pkgname/bin/arc "$pkgdir/usr/bin/arc"
}