blob: b431daa54b5070246222451f071394e69349f2f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
pkgname=arch-audit-git
pkgver=0.1.15.r58.g993b5b4
pkgrel=1
pkgdesc='A utility like pkg-audit based on Arch Security Team data'
url='https://gitlab.com/ilpianista/arch-audit'
depends=('glibc' 'gcc-libs' 'curl' 'libcurl.so' 'libalpm.so')
makedepends=('cargo' 'pkg-config' 'git' 'scdoc')
provides=('arch-audit')
conflicts=('arch-audit')
arch=('i686' 'x86_64')
license=('MIT')
source=('git+https://gitlab.com/ilpianista/arch-audit.git')
md5sums=('SKIP')
pkgver() {
cd arch-audit
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd arch-audit
cargo build --release --locked
}
check() {
cd arch-audit
cargo test --release --locked
}
package() {
cd arch-audit
make DESTDIR="${pkgdir}" PREFIX=/usr install
install -Dm 644 contrib/systemd/arch-audit.service -t "${pkgdir}/usr/share/${pkgname}"
install -Dm 644 contrib/systemd/arch-audit.timer -t "${pkgdir}/usr/share/${pkgname}"
install -Dm 644 contrib/hooks/arch-audit.hook -t "${pkgdir}/usr/share/${pkgname}"
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim: ts=2 sw=2 et:
|