blob: 772209b6c1e4db2660b6c2dfe0f17bdb18f52636 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
pkgname=arch-install-manager-git
_pkgname=arch-install-manager
pkgver=0.0.1.r41.gbb655d4
pkgrel=1
pkgdesc="A Linux Mint inspired GTK4-based install and update manager for Arch Linux (latest git)"
arch=('x86_64')
url="https://github.com/destbg/arch-install-manager"
license=('MIT')
depends=('gtk4' 'vte4' 'gtksourceview5' 'polkit' 'systemd' 'pacman' 'pacman-contrib' 'curl' 'git' 'base-devel')
provides=('arch-install-manager')
conflicts=('arch-install-manager')
makedepends=('cargo' 'git')
optdepends=('flatpak: Flatpak package support'
'meld: visual diff editor for pacnew files'
'timeshift: pre-update system snapshots'
'snapper: pre-update Btrfs snapshots'
'aur-scanner: scan AUR packages for security issues'
'rate-mirrors: refresh and rank the pacman mirror list')
source=("$pkgname::git+https://github.com/destbg/arch-install-manager.git#commit=bb655d4d870f450c5fc46be4391f9c747594b4ec")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long --tags --abbrev=7 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "$pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
package() {
cd "$pkgname"
for bin in daim daim-gui daim-helper daim-tray daim-check; do
install -Dm755 "target/release/$bin" "$pkgdir/usr/bin/$bin"
done
install -Dm644 "com.destbg.arch-install-manager.desktop" \
"$pkgdir/usr/share/applications/com.destbg.arch-install-manager.desktop"
install -Dm644 "com.destbg.arch-install-manager.policy" \
"$pkgdir/usr/share/polkit-1/actions/com.destbg.arch-install-manager.policy"
install -Dm644 "res/sysusers/daim-build.conf" \
"$pkgdir/usr/lib/sysusers.d/daim-build.conf"
install -Dm644 "res/systemd/daim-check.service" \
"$pkgdir/usr/lib/systemd/user/daim-check.service"
install -Dm644 "res/systemd/daim-check.timer" \
"$pkgdir/usr/lib/systemd/user/daim-check.timer"
install -Dm644 "res/systemd/daim-tray.service" \
"$pkgdir/usr/lib/systemd/user/daim-tray.service"
for size in 48x48 256x256 512x512; do
if [ -f "icons/$size/apps/arch-install-manager.png" ]; then
install -Dm644 "icons/$size/apps/arch-install-manager.png" \
"$pkgdir/usr/share/icons/hicolor/$size/apps/arch-install-manager.png"
fi
done
for sym in arch-install-manager-arch-symbolic arch-install-manager-flatpak-symbolic; do
if [ -f "icons/symbolic/apps/$sym.svg" ]; then
install -Dm644 "icons/symbolic/apps/$sym.svg" \
"$pkgdir/usr/share/icons/hicolor/symbolic/apps/$sym.svg"
fi
done
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|