blob: b8d2828934c239456276f30c455d4ec2658ee6f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Robin Candau <antiz@archlinux.org>
pkgname=arch-update-git
_pkgname="${pkgname%-git}"
pkgver=3.2.3.r415.af51378
pkgrel=1
pkgdesc="An update notifier & applier that assists you with important pre / post update tasks (git version)"
url="https://github.com/Antiz96/arch-update"
arch=('any')
license=('GPL-3.0-or-later')
depends=('bash' 'pacman-contrib' 'archlinux-contrib' 'curl' 'fakeroot' 'htmlq' 'diffutils' 'hicolor-icon-theme' 'python' 'python-pyqt6' 'qt6-svg' 'glib2')
makedepends=('git')
checkdepends=('bats')
optdepends=('yay: AUR Packages support'
'paru: AUR Packages support'
'flatpak: Flatpak Packages support'
'libnotify: Desktop notifications support on new available updates'
'vim: Default merge program for pacdiff'
'qt6-wayland: Systray applet support on Wayland'
'sudo: Privilege elevation'
'doas: Privilege elavation')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
printf "%s.r%s.%s" "$(git describe --tags --abbrev=0 | sed 's/^v//')" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
check() {
cd "${_pkgname}"
make test
}
package() {
cd "${_pkgname}"
make PREFIX=/usr DESTDIR="${pkgdir}" install
}
|