blob: 48e9c3859e14ef973b1f48521b7e2716f1294e8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
pkgname=arch-update-manager-bin
pkgver=3.6.1
pkgrel=1
pkgdesc="A Linux Mint inspired GTK4-based update manager for Arch Linux (prebuilt binary)"
arch=('x86_64')
url="https://github.com/destbg/arch-update-manager"
license=('MIT')
depends=('gtk4' 'vte4' 'gtksourceview5' 'polkit' 'pacman' 'pacman-contrib' 'expect' 'sudo' 'curl')
provides=('arch-update-manager')
conflicts=('arch-update-manager')
optdepends=('paru: AUR helper support'
'yay: AUR helper support'
'shelly: AUR helper support'
'flatpak: Flatpak package support'
'meld: visual diff editor for pacnew files'
'timeshift: pre-update system snapshots'
'snapper: pre-update Btrfs snapshots'
'aur-scanner: scan AUR packages for security issues'
'rate-mirrors: refresh and rank the pacman mirror list')
source=(
"arch-update-manager-${pkgver}-x86_64.tar.gz::${url}/releases/download/${pkgver}/arch-update-manager-${pkgver}-x86_64.tar.gz"
"${pkgname%-bin}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz"
)
sha256sums=('21798483b139bc42099dad4f1e8a16f797429f7dcfa322f50bbff3e02f905741'
'e0dc00e254dcad22b606027905e286d1abebc8a1c4494b4a6494a780721dbb60')
package() {
cd "$srcdir"
install -Dm755 arch-update-manager "$pkgdir/usr/bin/arch-update-manager"
if [[ -f arch-update-manager-tray ]]; then
install -Dm755 arch-update-manager-tray "$pkgdir/usr/bin/arch-update-manager-tray"
fi
if [[ -f arch-update-manager-check ]]; then
install -Dm755 arch-update-manager-check "$pkgdir/usr/bin/arch-update-manager-check"
fi
local srcdir_repo="${srcdir}/${pkgname%-bin}-${pkgver}"
install -Dm644 "${srcdir_repo}/arch-update-manager.desktop" \
"$pkgdir/usr/share/applications/arch-update-manager.desktop"
install -Dm644 "${srcdir_repo}/com.destbg.arch-update-manager.policy" \
"$pkgdir/usr/share/polkit-1/actions/com.destbg.arch-update-manager.policy"
if [[ -f "${srcdir_repo}/res/systemd/arch-update-manager-check.service" ]]; then
install -Dm644 "${srcdir_repo}/res/systemd/arch-update-manager-check.service" \
"$pkgdir/usr/lib/systemd/user/arch-update-manager-check.service"
fi
if [[ -f "${srcdir_repo}/res/systemd/arch-update-manager-check.timer" ]]; then
install -Dm644 "${srcdir_repo}/res/systemd/arch-update-manager-check.timer" \
"$pkgdir/usr/lib/systemd/user/arch-update-manager-check.timer"
fi
if [[ -f "${srcdir_repo}/res/systemd/arch-update-manager-tray.service" ]]; then
install -Dm644 "${srcdir_repo}/res/systemd/arch-update-manager-tray.service" \
"$pkgdir/usr/lib/systemd/user/arch-update-manager-tray.service"
fi
for size in 48x48 256x256 512x512; do
if [[ -f "${srcdir_repo}/icons/${size}/apps/arch-update-manager.png" ]]; then
install -Dm644 "${srcdir_repo}/icons/${size}/apps/arch-update-manager.png" \
"$pkgdir/usr/share/icons/hicolor/${size}/apps/arch-update-manager.png"
fi
done
install -Dm644 "${srcdir_repo}/LICENSE" "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}
|