summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b80a3b55932a6e02b206afc8d0b93546378429ff (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Marco Donadoni <marcodonadoni at live dot it>
# Contributor: Jeroen Rijken <jeroen dot rijken at gmail dot com>
pkgname=archi
pkgver=4.5.1
pkgrel=1
pkgdesc="Free, open source, cross-platform tool and editor to create ArchiMate models."
arch=('x86_64')
url="http://www.archimatetool.com/"
license=('MIT')
depends=('java-runtime-openjdk=8' 'bash')
optdepends=('webkitgtk2: hints view support')
provides=('archi')
source=("https://www.archimatetool.com/downloads/$pkgver/Archi-Linux64-$pkgver.tgz"
        "$pkgname.desktop"
        "$pkgname-launcher.sh"
        'LICENSE')
md5sums=('805623ada2fe99aea9178f9cd316f82d'
         '7b9a0cf8e67790ff9ca1afc6578e3adc'
         '7813e905142baeb290d396e349beeb13'
         '66653b079752362c3e9fc7142027cb7e')

package() {
  cd "$srcdir"

  # Docs
  install -d "$pkgdir/usr/share/doc/$pkgname"
  install -m644 Archi/docs/*       "$pkgdir/usr/share/doc/$pkgname/"
  install -m644 Archi/README       "$pkgdir/usr/share/doc/$pkgname/"

  # Icon and desktop file
  install -Dm644 Archi/icon.xpm     "$pkgdir/usr/share/pixmaps/$pkgname.xpm"
  install -Dm644 "$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"

  # Launcher
  install -Dm755 "$pkgname-launcher.sh" "$pkgdir/usr/bin/$pkgname"
  
  # Copy binaries
  rm -R Archi/docs
  rm Archi/icon.xpm Archi/README Archi/Archi-Ubuntu.sh
  install -d "$pkgdir/opt"
  cp -R Archi/ "$pkgdir/opt/$pkgname"
  chmod 755 "$pkgdir/opt/$pkgname/Archi"

  # Install license
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}