PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Gabriel Chamon <gchamon@tuta.io>
pkgname=archie-cli
pkgver=0.4.0
pkgrel=1
_commit=76caf94548cf76f2399d9a7446da15e0daa22685
pkgdesc="Archlinux system operation and maintenance CLI/applet"
arch=(any)
url="https://gitlab.com/gabriel.chamon/archie"
license=(MIT)
depends=("python>=3.14" sqlite)
makedepends=(python-installer uv)
provides=(archie)
conflicts=(archie archie-cli-nightly)
source=("archie::git+https://gitlab.com/gabriel.chamon/archie.git#commit=${_commit}")
sha256sums=('SKIP')

build() {
    cd "$srcdir/archie"
    sed -i "s/^version = \"[^\"]*\"/version = \"$pkgver\"/" pyproject.toml
    uv build --wheel --out-dir "$srcdir/dist"
}

package() {
    cd "$srcdir/archie"
    python -m installer --destdir="$pkgdir" "$srcdir"/dist/*.whl
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 docs/user/KEYBOARD_SHORTCUTS.md "$pkgdir/usr/share/doc/$pkgname/KEYBOARD_SHORTCUTS.md"
    install -Dm644 deployment-packages/local/lib/zsh/README.md "$pkgdir/usr/share/doc/$pkgname/ZSH_COMMANDS.md"
    install -Dm644 packaging/archie-cli/_archie "$pkgdir/usr/share/zsh/site-functions/_archie"
    install -Dm644 packaging/archie-cli/archie.sysusers "$pkgdir/usr/lib/sysusers.d/archie.conf"
    install -Dm644 packaging/archie-cli/archie.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/archie.conf"
}