blob: 2bf310d7f38b15c1a033723f73d9da98d14220a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Miten <admin@m1ten.me>
# Maintainer: Anton Hvornum <anton@hvornum.se>
_name=archinstall
pkgname=archinstall-git
pkgver=2.5.4.r7.gc3e3ac6
pkgrel=1
pkgdesc="Just another guided/automated Arch Linux installer with a twist"
arch=('any')
url="https://github.com/archlinux/$_name"
license=('GPL3')
depends=('python' 'systemd')
makedepends=('git' 'python-setuptools' 'python-sphinx' 'python-build' 'python-installer' 'python-wheel')
optdepends=('python-systemd: Adds journald logging')
provides=('python-archinstall' 'archinstall')
conflicts=('python-archinstall' 'archinstall')
replaces=('python-archinstall' 'archinstall')
source=("git+https://github.com/archlinux/$_name.git")
sha256sums=('SKIP')
pkgver() {
cd "$_name"
git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd $_name
# Remove symlinks from the package source
# and move the actual files in before packaging.
rm -fv $_name/{examples,profiles}
mv -v examples profiles $_name/
}
build() {
cd "$_name"
python -m build --wheel --no-isolation
PYTHONDONTWRITEBYTECODE=1 make man -C docs
}
package() {
cd "$_name"
# We have previously added "--optimize=1", "--skip-build" and "--prefix=/usr" here.
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm 644 docs/_build/man/archinstall.1 -t "${pkgdir}/usr/share/man/man1/"
}
|