blob: a0ff10d128480766304db355e5a3784c3140a97c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Maintainer: Isabell Cowan < izzi at izzette com >
# Contributer: Martin Trigaux <me@mart-e.be>
_pkgname='ardor'
pkgbase="$_pkgname-system"
pkgname=("$pkgbase")
pkgver=2.2.2
pkgrel=1
pkgdesc="The Ardor Reference Software Client -- Secure System Installation."
url="https://www.ardorplatform.org"
license=('MIT' 'GPL')
install="${pkgname[0]}.install"
source=("http://bitbucket.org/Jelurida/ardor/downloads/ardor-client-$pkgver.zip"
'ardor.desktop'
'ardor.default'
'ardor.service')
sha256sums=('4d5aa5ade0de7c4ae1ff2fc3ff75d5fdbffd6b5dc15a2673ef99db0caab12c54'
'a6787a24aad510f3b4f8b6c724221a9518c34298425c9b93f9ac4ded94ba4544'
'1fd2eb63c2778279f9e17cafa650399ed67bc8ba2428745bd56a01d41e949ff5'
'9e9540a65c661f6ece0113726549df11735ee75b122b4751412cae79f9c4b362')
arch=('any')
backup=('opt/ardor/conf/data/PUBLIC_KEY.json'
'opt/ardor/conf/data/IGNIS-testnet.json'
'opt/ardor/conf/data/AEUR.json'
'opt/ardor/conf/data/ARDR-testnet.json'
'opt/ardor/conf/data/ACCOUNT_CONTROL.json'
'opt/ardor/conf/data/BITSWIFT.json'
'opt/ardor/conf/data/PUBLIC_KEY-testnet.json'
'opt/ardor/conf/data/ACCOUNT_PROPERTIES.json'
'opt/ardor/conf/data/ASSETS-testnet.json'
'opt/ardor/conf/data/IGNIS.json'
'opt/ardor/conf/data/IGNIS_CURRENCIES-testnet.json'
'opt/ardor/conf/data/ASSETS.json'
'opt/ardor/conf/data/IGNIS_ALIASES.json'
'opt/ardor/conf/data/ACCOUNT_INFO.json'
'opt/ardor/conf/data/IGNIS_ALIASES-testnet.json'
'opt/ardor/conf/data/BITSWIFT-testnet.json'
'opt/ardor/conf/data/ACCOUNT_INFO-testnet.json'
'opt/ardor/conf/data/ARDR.json'
'opt/ardor/conf/data/AEUR-testnet.json'
'opt/ardor/conf/data/IGNIS_CURRENCIES.json'
'opt/ardor/conf/data/ACCOUNT_CONTROL-testnet.json'
'opt/ardor/conf/data/ACCOUNT_PROPERTIES-testnet.json'
'opt/ardor/conf/nxt-default.properties'
'opt/ardor/conf/logging-default.properties'
'etc/default/ardor')
depends=('jre8-openjdk')
conflicts=('ardor')
provides=('ardor')
# Takes forever, is pointless ...
options=('!strip' 'emptydirs')
package() {
msg2 "Installing ardor client..."
install -dm755 "$pkgdir/opt/ardor"
cp -r "$_pkgname/." "$pkgdir/opt/ardor"
rm -f "$pkgdir/opt/ardor/conf/.lock"
rm -rf --preserve-root "$pkgdir/opt/ardor/logs"
install -dm755 "$pkgdir/opt/ardor/.ardor"
msg2 "Removing unneeded files for windows..."
rm -f -- "$pkgdir/opt/ardor"/*.{bat,exe}
msg2 "Correcting permissions..."
find "$pkgdir/opt/ardor" -type d -exec chmod 0755 \{\} +
find "$pkgdir/opt/ardor" -maxdepth 1 -type f -executable -name \*.sh -exec chmod 0755 \{\} +
find "$pkgdir/opt/ardor" -type f \! \( -executable -a -name \*.sh \) -exec chmod 0644 \{\} +
chmod 0750 "$pkgdir/opt/ardor/conf/data"
chmod 0640 "$pkgdir/opt/ardor/conf/nxt-default.properties"
msg2 "Installing ardor icon..."
install -Dm644 \
"$srcdir/$_pkgname/html/www/img/nxt-icon-32x32.png" \
"$pkgdir/usr/share/icons/hicolor/32x32/apps/ardor.png"
msg2 "Installing ardor.desktop..."
install -Dm644 \
"$srcdir/ardor.desktop" \
"$pkgdir/usr/share/applications/ardor.desktop"
msg2 "Installing ardor ${license[0]} license(s)..."
install -dm755 "$pkgdir/usr/share/licenses/ardor"
mv \
"$pkgdir/opt/ardor/LICENSE.txt" \
"$pkgdir/opt/ardor/3RD-PARTY-LICENSES.txt" \
"$pkgdir/usr/share/licenses/ardor/"
msg2 "Creating ardor database directory..."
install -dm750 "$pkgdir/var/lib/ardor"
ln -s \
"/var/lib/ardor" \
"$pkgdir/opt/ardor/nxt_db"
msg2 "Creating ardor log directory..."
install -dm755 "$pkgdir/var/log/ardor"
ln -s \
"/var/log/ardor" \
"$pkgdir/opt/ardor/logs"
msg2 "Installing ardor.default..."
install -Dm644 \
"$srcdir/ardor.default" \
"$pkgdir/etc/default/ardor"
msg2 "Installing ardor systemd service..."
install -Dm644 \
"$srcdir/ardor.service" \
"$pkgdir/usr/lib/systemd/system/ardor.service"
}
# vim: set ts=2 sw=2 et syn=sh:
|