summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b121277f621cfc9ed8cfdd93394d590e6263adb9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer Martin Peres <martin.peres@ensi-bourges.fr>
pkgname=arduide-git
pkgver=0.r360.9fc057e
pkgrel=1
pkgdesc="ArduIDE is a Qt-based IDE for the open-source Arduino electronics prototyping platform."
arch=('i686' 'x86_64')
url="http://mupuf.org/project/arduide.html"
license=('GPL')
depends=('qt4>=4.5' 'qtwebkit' 'qscintilla-qt4' 'grantlee-qt4>=0.1' 'udev' 'gcc-libs' 'avr-gcc' 'avr-libc' 'avrdude')
makedepends=('git' 'cmake')

source=("${pkgname}::git+https://github.com/mupuf/arduide.git")
sha256sums=('SKIP')

prepare() {
  msg "Cleaning the previous build directory..."
  rm -rf build
  mkdir build
}

pkgver() {
  cd ${pkgname}
  printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd build
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DUSE_FHS_PATHS=ON \
        -DCMAKE_BUILD_TYPE=Release \
        -DQT_QMAKE_EXECUTABLE=qmake-qt4 \
        ../${pkgname}
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}