summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: aa99cd6675f38392ace080e9c8e9dc3d28584efb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Sebba <sebba at cock dot li>
pkgname=arena-tracker-git
_pkgname=arena-tracker
pkgver=r550.9f23cec
pkgrel=1
pkgdesc="Hearthstone tool to track cards in Arena."
arch=(x86_64)
url="https://github.com/supertriodo/Arena-Tracker/"
license=('GPL')
depends=('opencv2' 'qt5-base')
provides=('arena-tracker-git' 'arena-tracker')
conflicts=('arena-tracker')
source=("$pkgname::git+https://github.com/supertriodo/Arena-Tracker.git"
		"$_pkgname.desktop"
    "unixpaths.patch")
md5sums=('SKIP'
         '5a5e0e1296da4fe10c3cc78d1123060c'
         '590026eee3c4990a9ce283aa0432c1c0')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  patch -p0 "$srcdir/$pkgname/Sources/utility.cpp" < unixpaths.patch
}

build() {
	cd "$pkgname"
	qmake .
	make
}

package() {
  cd "$srcdir/$pkgname/"
  install -d -m 755 ${pkgdir}/usr/share/${_pkgname}/extra
  install -d -m 755 ${pkgdir}/usr/share/doc/${_pkgname}
  install -D -m 755 ArenaTracker ${pkgdir}/usr/bin/${_pkgname}
  install -D -m 644 ArenaTracker.ico $pkgdir/usr/share/pixmaps/${_pkgname}.ico
  install -D -m 644 Extra/arenaTemplate.png ${pkgdir}/usr/share/${_pkgname}/extra/arenaTemplate.png
  install -D -m 644 Extra/collectionTemplate.png ${pkgdir}/usr/share/${_pkgname}/extra/collectionTemplate.png
  install -D -m 644 Extra/deckBuilder.py ${pkgdir}/usr/share/${_pkgname}/extra/deckBuilder.py
  install -D -m 644 $srcdir/$_pkgname.desktop $pkgdir/usr/share/applications/$_pkgname.desktop
  install -D -m 644 Fonts/hsFont.ttf $pkgdir/usr/share/fonts/TTF/hsFont.ttf
  install -D -m 644 README.md ${pkgdir}/usr/share/doc/${_pkgname}
}