blob: 25a63317c29cc0a392ea78cc647385c5f1a5b651 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Calixte Pernot - <cpernot at praksys dot net>
# Maintainer: Louis Dupraz - <louis at gottagofast dot fr>
pkgname=ariane-git
_pkgname=ariane
pkgver=1.0.0
pkgrel=2
pkgdesc="Fast initramfs/UKI generator with encryption and secure boot support"
arch=(x86_64)
url='https://gitlab.com/cpernot/ariane'
license=('GPL-3.0-only')
depends=("kmod" "util-linux-libs" "zstd" "libarchive")
makedepends=("rust" "cargo" "git" "pkg-config" "clang")
optdepends=(
'sbctl: Secure Boot signing support'
)
provides=(initramfs)
conflicts=(ariane)
source=("$_pkgname::git+$url")
sha256sums=("SKIP")
pkgver() {
cd "$srcdir/$_pkgname"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
# Ariane
cd "$srcdir/$_pkgname"
cargo fetch --manifest-path Cargo.toml
# ariane-init
cd "$srcdir/$_pkgname/init/"
cargo fetch --manifest-path Cargo.toml
cd "$srcdir/$_pkgname/alpm_hooks/script/"
cargo fetch --manifest-path Cargo.toml
}
build() {
# Ariane
cd "$srcdir/$_pkgname"
export CARGO_TARGET_DIR=target
echo "Building ariane"
cargo build --frozen --release --all-features --manifest-path Cargo.toml
# ariane-init
cd "$srcdir/$_pkgname/init/"
echo "Building ariane-init"
cargo build --frozen --release --manifest-path Cargo.toml
cd "$srcdir/$_pkgname/alpm_hooks/script/"
echo "Builing ALPM Hook helper"
cargo build --frozen --release --manifest-path Cargo.toml
}
package() {
cd "$srcdir/$_pkgname"
install -Dm0755 "target/release/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
install -Dm0755 "init/target/release/$_pkgname-init" "$pkgdir/usr/lib/$_pkgname/$_pkgname-init"
install -Dm0755 "alpm_hooks/script/target/release/ariane_helper" "$pkgdir/usr/share/libalpm/scripts/ariane_helper"
install -Dm0644 "alpm_hooks/hooks/60-ariane-remove.hook" "$pkgdir/usr/share/libalpm/hooks/60-ariane-remove.hook"
install -Dm0644 "alpm_hooks/hooks/90-ariane-install.hook" "$pkgdir/usr/share/libalpm/hooks/90-ariane-install.hook"
install -Dm0644 "ariane_build.h" "$pkgdir/usr/include/ariane/builder.h"
install -Dm0644 "init/ariane_init.h" "$pkgdir/usr/include/ariane/init.h"
mkdir -p "$pkgdir/etc/ariane.d/"
}
|