blob: f0d800b31c689a1fe0922214b0c3bb65ceca54d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
_name=arkenfox
_repo=user.js
_base=${_name}-${_repo}
pkgname=${_base}-git
pkgver=117.0.r0.g1e6e211
pkgrel=1
pkgdesc="Firefox privacy, security and anti-tracking: a comprehensive user.js template for configuration and hardening."
arch=('any')
url="https://github.com/${_name}/${_repo}"
license=('MIT')
makedepends=('git')
provides=("${_base}")
conflicts=("${_base}")
options=('!strip')
source=(
"${_repo}::git+${url}"
"01-updater.patch"
"02-cleaner.patch"
)
sha256sums=(
'SKIP'
'aec6852c49f697a9f00229a028df73fdc98a3841f066d56280b5f7992d796e78'
'6cb83edb60a8affdab79b361c3ad52f1f70d3c4d123e8be0b409441e6a752691'
)
pkgver() {
cd "${_repo}"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
for p in *.patch; do
patch -p0 -d "${_repo}" < "${p}"
done
}
package() {
local lib="/usr/lib/${pkgname}"
local bin="/usr/bin"
install -dm755 "${pkgdir}"{"${lib}","${bin}"}
cd "${_repo}"
local updater="updater.sh"
local cleaner="prefsCleaner.sh"
install -Dm755 -t "${pkgdir}${lib}" "${updater}" "${cleaner}"
install -Dm644 -t "${pkgdir}${lib}" "user.js"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "LICENSE.txt"
ln -s "${lib}/${updater}" "${pkgdir}${bin}/${_name}-updater"
ln -s "${lib}/${cleaner}" "${pkgdir}${bin}/${_name}-cleaner"
}
|