blob: 75c847b511ea6dbdf2e8e4d4812b5ef4cd2dfb77 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Contributor: Alexander 'hatred' Drozdov <adrozdoff@gmail.com>
# Contributor: toha257 <toha257@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>
# Maintainer: Tavian Barnes <tavianator@tavianator.com>
_target="arm-linux-gnueabihf"
pkgname=${_target}-gcc-stage2
pkgver=7.1.1
_pkgver=${pkgver:0:1}
_islver=0.18
pkgrel=4
_commit=d791474f3fc2133fa0c310e566988b0cbdff321e
pkgdesc="The GNU Compiler Collection. Stage 2 for toolchain building (${_target})"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL' 'custom')
url="http://gcc.gnu.org"
depends=("${_target}-binutils>=2.28.0-4" "${_target}-glibc-headers>=2.25-7" 'libmpc' 'zlib')
options=('!emptydirs' '!distcc' '!strip')
conflicts=("${_target}-gcc-stage1")
replaces=("${_target}-gcc-stage1")
provides=("${_target}-gcc-stage1=${pkgver}")
source=(https://github.com/gcc-mirror/gcc/archive/${_commit}.tar.gz
http://isl.gforge.inria.fr/isl-${_islver}.tar.bz2
Revert-eeb6872bf.patch)
md5sums=('22748db692c5e409b7f3fa9482faa9cb'
'11436d6b205e516635b666090b94ab32'
'e4c9c8b498b04c0f51d219d025ca8407')
prepare() {
mv gcc-${_commit}* gcc
cd ${srcdir}/gcc
# link isl for in-tree build
ln -s ../isl-${_islver} isl
# Do not run fixincludes
sed -i 's@\./fixinc\.sh@-c true@' gcc/Makefile.in
# hack! - some configure tests for header files using "$CPP $CPPFLAGS"
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" {libiberty,gcc}/configure
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=80717
patch -p1 -i ${srcdir}/Revert-eeb6872bf.patch
mkdir ${srcdir}/gcc-build
}
build() {
cd ${srcdir}/gcc-build
# using -pipe causes spurious test-suite failures
# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=48565
CFLAGS=${CFLAGS/-pipe/}
CXXFLAGS=${CXXFLAGS/-pipe/}
${srcdir}/gcc/configure --prefix=/usr \
--program-prefix=${_target}- \
--with-local-prefix=/usr/${_target} \
--with-sysroot=/usr/${_target} \
--with-build-sysroot=/usr/${_target} \
--with-as=/usr/bin/${_target}-as \
--with-ld=/usr/bin/${_target}-ld \
--libdir=/usr/lib \
--libexecdir=/usr/lib \
--disable-nls \
--enable-languages=c,c++ \
--disable-shared \
--disable-threads \
--with-system-zlib \
--with-isl \
--enable-__cxa_atexit \
--disable-libunwind-exceptions \
--enable-clocale=gnu \
--disable-libstdcxx-pch \
--disable-libssp \
--enable-gnu-unique-object \
--enable-linker-build-id \
--disable-lto \
--disable-plugin \
--enable-install-libiberty \
--with-linker-hash-style=gnu \
--enable-gnu-indirect-function \
--disable-multilib \
--disable-werror \
--enable-checking=release \
--enable-default-pie \
--enable-default-ssp \
--target=${_target} \
--host=${CHOST} \
--build=${CHOST} \
--with-arch=armv6 \
--with-float=hard \
--with-fpu=vfp
make all-gcc all-target-libgcc
}
package() {
cd ${srcdir}/gcc-build
make DESTDIR=${pkgdir} install-gcc install-target-libgcc
rm -rf ${pkgdir}/usr/share
# strip it manually
strip ${pkgdir}/usr/bin/* 2>/dev/null || true
find ${pkgdir}/usr/lib -type f -exec /usr/bin/${_target}-strip \
--strip-unneeded {} \; 2>/dev/null || true
}
|