blob: caf2278d36f3dccbcc1629d78391780a7204b530 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
_target=armv8l-linux-gnueabihf
pkgname=$_target-gdb
pkgver=7.11
pkgrel=1
pkgdesc='The GNU Debugger for the ARM hard float target'
arch=(i686 x86_64)
url='http://www.gnu.org/software/gdb/'
license=(GPL3)
depends=(xz ncurses expat python2 guile)
makedepends=(texinfo)
options=(!emptydirs)
source=(http://ftp.gnu.org/gnu/gdb/gdb-$pkgver.tar.xz)
sha256sums=('7a434116cb630d77bb40776e8f5d3937bed11dea56bafebb4d2bc5dd389fe5c1')
build() {
cd gdb-$pkgver
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
./configure --target=$_target \
--prefix=/usr \
--enable-multilib \
--enable-interwork \
--with-system-readline \
--disable-nls \
--with-python=/usr/bin/python2 \
--with-system-gdbinit=/etc/gdb/gdbinit
make
}
package() {
cd gdb-$pkgver
make DESTDIR="$pkgdir" install
# Following files conflict with 'gdb' package
rm -r "$pkgdir"/usr/share/info
# TOTHINK: we remove python module used for debugging. It means arm-*-gdb alone will not be able to debug and 'gdb' package
# should be installed. File a bug upstream - ask a separate python module folder for cross tools.
rm -r "$pkgdir"/usr/share/gdb
rm -r "$pkgdir"/usr/include/gdb
rm -r "$pkgdir"/usr/share/man/man5
}
|