blob: 09301732506ad4c9ca729197b6e31ca52d65afa1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=arptables-git
pkgver=0.0.4.r17.g28b22d5
pkgrel=1
pkgdesc="ARP filtering utility"
arch=('i686' 'x86_64')
url="https://ebtables.netfilter.org/"
license=('GPL2')
depends=('glibc' 'perl')
makedepends=('git')
provides=('arptables')
conflicts=('arptables')
backup=('etc/arptables.conf')
source=("git://git.netfilter.org/arptables"
"arptables.service::https://git.archlinux.org/svntogit/packages.git/plain/trunk/arptables.service?h=packages/arptables"
"arptables.systemd::https://git.archlinux.org/svntogit/packages.git/plain/trunk/arptables.systemd?h=packages/arptables")
sha256sums=('SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "arptables"
git describe --long --tags | sed 's/^arptables-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "arptables"
make
}
package() {
cd "arptables"
make \
DESTDIR="$pkgdir" \
PREFIX="/usr" \
LIBDIR="/usr/lib/arptables" \
BINDIR="/usr/bin" \
MANDIR="/usr/share/man" \
install
install -Dm755 "$srcdir/arptables.systemd" \
"$pkgdir/usr/lib/systemd/scripts/arptables"
install -Dm644 "$srcdir/arptables.service" \
"$pkgdir/usr/lib/systemd/system/arptables.service"
install -Dm644 /dev/null "$pkgdir/etc/arptables.conf"
}
|