blob: 09c3d13fdacd8fdf0f6c8f3511b73140ba3d7495 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: <gaelic>
# Contributor: Anatoly Bashmakov anatoly at posteo dot net
pkgname=asciidoctor-pdf
pkgver=2.3.17
pkgrel=1
pkgdesc="Translate asciidoctor directly to pdf"
arch=(any)
url="https://github.com/asciidoctor/asciidoctor-pdf"
license=(MIT)
depends=(
asciidoctor
ruby
ruby-concurrent
ruby-matrix
ruby-prawn
ruby-prawn-icon
ruby-prawn-svg
ruby-prawn-table
ruby-prawn-templates
ruby-treetop
)
makedepends=(rubygems)
checkdepends=(
gsfonts
poppler
ruby-chunky_png
ruby-coderay
ruby-pdf-inspector
ruby-rspec
)
optdepends=('ruby-coderay: for syntax highlighting')
options=(!emptydirs)
source=(
"$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
"remove-failing-tests.patch"
)
sha256sums=(
'729320de291fe26a1fb18bbed5259b46ca686b1e69f2f2dd1947923d369ec8ac'
'40e0aea913c4abc3313b9ae05957e334510899ae64fd882a898144c9ede025d4'
)
_archive="$pkgname-$pkgver"
prepare() {
cd "$_archive"
# update gemspec/Gemfile to allow newer version of the dependencies
sed -i -E 's|~>|>=|g' "$pkgname.gemspec"
patch --forward --strip=1 --input="$srcdir/remove-failing-tests.patch"
}
build() {
cd "$_archive"
local gemdir="$(gem env gemdir)"
gem build "$pkgname.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/$gemdir" \
--bindir "tmp_install/usr/bin" \
"$pkgname-$pkgver.gem"
# remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/$gemdir/cache/" \
"tmp_install/$gemdir/gems/$pkgname-$pkgver/vendor/" \
"tmp_install/$gemdir/doc/$pkgname-$pkgver/ri/ext/"
find "tmp_install/$gemdir/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/$gemdir/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd "$_archive"
GEM_HOME="tmp_install/$(gem env gemdir)" rspec
}
package() {
cd "$_archive"
cp -a -t "$pkgdir" tmp_install/*
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.adoc
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|