blob: 0d09d21ca642eb9eaa947a6feafe957b15261d5d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Gilrain <gilrain+libre.arch A_T castelmo DOT_ re>
pkgname="asf"
pkgver="3.0.5.9"
pkgrel=1
pkgdesc="Steam cards farmer."
arch=('any')
url="https://github.com/JustArchi/ArchiSteamFarm"
license=('Apache')
depends=('dotnet-runtime')
makedepends=('p7zip')
changelog=changelog
backup=('var/lib/asf/config/ASF.json')
install=${pkgname}.install
source=("${pkgname}-${pkgver}.zip::https://github.com/JustArchi/ArchiSteamFarm/releases/download/${pkgver}/ASF-generic.zip"
"${pkgname}.sh"
"${pkgname}.service"
"${pkgname}-user.service"
"${pkgname}.sysusers"
"NLog.config")
sha256sums=('0c8904c87d7fe74281469f14705679b80f62809e567bf8b64b15dfd63a56547d'
'8d76996c1024b80704b25af8a8800ef3f8a8a518d19c2a1e85ba62b58b22cdfd'
'e63b55f65e1c0c935945bd788f47a77be82e96a409b64660b5a96b9c190964ff'
'dcaf43586125e07488e338438158097b31ba335fcb238127dfb785a41d223f49'
'883373be23f6f49ae597f61c1310d8cd45bce7c3ee1b5d456ffc9fedbe7dd486'
'cd2c704c01217c103f8ad1729920a142f63f686351c6a9557c50a33fb3c723fe')
noextract=('asf-3.0.5.9.zip')
prepare() {
7z x -o"${srcdir}/asf" ${pkgname}-${pkgver}.zip
}
package() {
install -d -m 755 "${pkgdir}/usr/lib/${pkgname}"
cp -rdp --no-preserve=ownership "${srcdir}/asf" "${pkgdir}/usr/lib"
find "${pkgdir}/usr/lib/${pkgname}" -type f -exec chmod 644 {} \;
find "${pkgdir}/usr/lib/${pkgname}" -type d -exec chmod 755 {} \;
install -d -m 755 "${pkgdir}/var/lib/${pkgname}/config"
mv "${pkgdir}/usr/lib/${pkgname}/config" "${pkgdir}/var/lib/${pkgname}"
ln -sf "/var/lib/${pkgname}/config" "${pkgdir}/usr/lib/${pkgname}/config"
install -D -m755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
install -D -m644 "${srcdir}/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
install -D -m644 "${srcdir}/${pkgname}-user.service" "${pkgdir}/usr/lib/systemd/user/${pkgname}.service"
install -D -m644 "${srcdir}/${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -D -m644 "${srcdir}/NLog.config" "${pkgdir}/usr/lib/${pkgname}/NLog.config"
# disable auto-updates and version checks
sed -i 's/"UpdateChannel": 1/"UpdateChannel": 0/g' "${pkgdir}/var/lib/${pkgname}/config/ASF.json"
sed -i 's/"UpdatePeriod": 24/"UpdatePeriod": 0/g' "${pkgdir}/var/lib/${pkgname}/config/ASF.json"
}
|