blob: a65126cc157b2f1486faae76a721f7ecea5e9cf9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Simone Camito <zibo.camito@gmail.com>
_pkgname=ashell
pkgname="${_pkgname}-git"
pkgver=r113.3c2d6e5
pkgrel=1
pkgdesc="A ready to go Wayland status bar for Hyprland"
_git="https://github.com/MalpenZibo/${_pkgname}.git"
url="${_git}"
license=("MIT")
provides=("${_pkgname}")
conflicts=("${_pkgname}")
makedepends=(
"cargo"
"git"
"wayland-protocols"
"clang"
)
depends=(
"libxkbcommon"
"wayland"
"dbus"
"libpipewire"
"libpulse"
)
arch=("x86_64")
source=(${_pkgname}::git+${_git})
b2sums=('SKIP')
pkgver() {
cd "${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${_pkgname}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${_pkgname}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
package() {
cd "${_pkgname}"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/${_pkgname}"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|