summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6a121414cbc13d787aabcbfe3d1a2de525dbb99d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Kenneth Endfinger <kaendfinger@gmail.com>
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: Vincent Bernardoff <vb@luminar.eu.org>

pkgname=aspcud
pkgver=1.9.5
pkgrel=1
pkgdesc='Solver for package dependencies'
arch=('x86_64')
url='https://potassco.org/aspcud'
license=('GPL3')
makedepends=('boost' 'cmake' 'git' 'ninja' 're2c')
depends=('clingo')
source=("git+https://github.com/potassco/$pkgname#tag=v$pkgver")
md5sums=('SKIP')

build() {
  mkdir -p build
  cd build
  cmake "../$pkgname" \
    -DCMAKE_INSTALL_PREFIX:PATH=/usr \
    -DCMAKE_INSTALL_LIBDIR:PATH=lib \
    -DCUDF2LP_LOC=cudf2lp \
    -DGRINGO_LOC=gringo \
    -DCLASP_LOC=clasp \
    -DCMAKE_BUILD_TYPE=Release \
    -GNinja
  ninja
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
}

# vim: ts=2 sw=2 et: