blob: 2233177b43fb1cdb5282bcc715fcaa4f3cd0e9e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: wackbyte <wackbyte@protonmail.com>
pkgname=asphalt
pkgver=0.9.1
pkgrel=1
pkgdesc='Upload and reference Roblox assets in code'
arch=('aarch64' 'arm' 'armv6h' 'armv7h' 'i686' 'x86_64')
url='https://github.com/jackTabsCode/asphalt'
license=('MIT')
depends=('gcc-libs' 'glibc')
makedepends=('cargo')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
b2sums=('37addbf3f36c3a50994933f80cac54892860a12f63778a818279f9d502799863bcedb8f8939fb555611c52169861ffb86b42b169763e604cf0dacbdc7d343f84')
options=(!lto)
prepare() {
export RUSTUP_TOOLCHAIN=stable
cd "${pkgname}-${pkgver}"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "${pkgname}-${pkgver}"
cargo build --frozen --release
}
check() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "${pkgname}-${pkgver}"
cargo test --frozen
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm755 -t "${pkgdir}/usr/bin" "target/release/${pkgname}"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
}
|