PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Antonio Bartalesi <antonio.bartalesi@gmail.com>

_name="Astor"
pkgname=${_name,,}
pkgver=7.5.3
_jarfile="${_name}-${pkgver}-jar-with-dependencies.jar"
pkgrel=3
pkgdesc="A graphical Tango control system administration tool"
arch=('any')
url="https://gitlab.com/tango-controls/${_name}"
license=('GPL3')
depends=('java-runtime=8' jdk8-openjdk sh)
makedepends=(maven)
source=(
  https://gitlab.com/tango-controls/${_name}/-/archive/${pkgver}/${_name}-${pkgver}.tar.gz
  launcher pom.patch
)
sha256sums=(
  'd575c5be3212a458ff06ce5a9bb8fefc1ef09d13531992a5f4f3827c4f89aff4'
  '25cc409561647519ad0bb2ffc00abb9cd923626f978f49c03b1f72b1fcd47d0b'
  '15c1bbbf1c1544eb18af057ce4b00c65691476ac52a8b8638e0afcc0579976cd'
)

prepare() {
  sed -i "s/jar_file/$_jarfile/" launcher
  patch --directory="$_name-$pkgver" --forward --strip=1 --input="${srcdir}/pom.patch"
}

build() {
  cd ${_name}-${pkgver}
  mvn package
}

package() {
  cd ${srcdir}
  install -D -m755 ${srcdir}/${_name}-${pkgver}/target/${_jarfile} ${pkgdir}/usr/share/java/${pkgname}/${_jarfile}
  install -D -m755 ${srcdir}/launcher ${pkgdir}/usr/bin/${pkgname}
}