blob: 916e6dc893bb0fdbe005f350d3eed6e75f2eaea8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
# Contributor: Andre Miranda <andreldm1989 AT gmail DOT com>
# Contributor: Tom Bu <tom.bu AT members.fsf.org>
# Contributor: John Reese <john@noswap.com>
# Contributor: Jordan J Klassen <forivall@gmail.com>
# Contributor: Danny Arnold <despair.blue at gmail dot com>
pkgname=atom-editor-bin
pkgver=1.38.0
pkgrel=1
pkgdesc="Hackable text editor built on Electron (official precompiled binary)"
arch=('x86_64')
url="https://github.com/atom/atom"
license=('MIT')
provides=('atom' 'apm')
options=(!strip !emptydirs)
depends=('git' 'gconf' 'gtk2' 'libnotify' 'libxtst' 'nss' 'python2' 'xdg-utils' 'desktop-file-utils' 'alsa-lib' 'libgnome-keyring' 'libxss')
optdepends=('gvfs')
conflicts=('atom' 'atom-editor' 'atom-editor-git' 'atom-editor-git-tagged' 'apm' 'atom-notracking')
install=$pkgname.install
source=("atom-amd64-v${pkgver}.deb::https://atom-installer.github.com/v${pkgver}/atom-amd64.deb"
"LICENSE::https://raw.githubusercontent.com/atom/atom/v${pkgver}/LICENSE.md"
atom-editor-bin.install
atom-python.patch
startupwmclass.patch)
sha512sums=('1c23b83a7aafe2f94fce0605b5df9d6e604192156303c7d656d25b0614ddcd320d9d68597ebe4f750ae41ebd2b19ca531e3a2401c4753fb267164ca3fe65ccbf'
'ab419ebc3eeecc4df894de6d4e8f7d0e7f1a8a650789d497c1f3754e6af0acedeb50257024e2fa123c0b3dafd12b97fd6d671ef1c450b3fa43291d2a1db0209f'
'e30f7e4812898b80c079ba419e0cb37522c2e154ef7fdd6dda3da06dcbcaadc42016dd3d3b8caf206b842a2b9e3b954e537626d72337c56f05365a733627ce6c'
'37e33402ff1a21c27debc56ac909279992c6a3aa9f2d8dd49fb13fc02cc3fb91a373531be92df9cc81089e167827ca7b36f967e4f7e482b1173d358a8b29cb98'
'374b9f8fa1e0d2cab77d4cea9c718fb889bb6db3dbf9762ad5cbb88f3a0936023f36641012fc90e029832a772b8d4fdfe6b72f304e3950c02a7c9bf4d6d3d4ec')
prepare() {
# Extract data
bsdtar xf data.tar.xz
# Apply patches
patch -sp1 < "${srcdir}"/atom-python.patch
patch -sp1 < "${srcdir}"/startupwmclass.patch
# Modify package to use python2 instead of python3
sed -i 's|env PYTHON=python2 GTK_IM_MODULE= QT_IM_MODULE= XMODIFIERS= /usr/share/atom/atom|/usr/bin/atom|' usr/share/applications/atom.desktop
sed -i 's|python|python2|' usr/share/atom/resources/app/apm/bin/python-interceptor.sh
}
package() {
# Recursively remove group's write permission before moving to package directory
chmod -R g-w usr
mv usr "${pkgdir}"
# Add LICENSE
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
}
|