1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Contributor: Matheus de Alcantara <matheus.de.alcantara@gmail.com>
# Maintainer: Brenton Horne <brentonhorne77 at gmail dot com>
_pkgname=atom
_version=git
# Module Versions
_fus_url="https://github.com/fusion809"
_language_gfm2_ver=0.92.2
_language_ini_desktop_ver=1.18.3
_language_liquid_ver=0.5.1
_language_patch2_url="${_fus_url}/language-patch2"
_language_patch2_ver=1.0.0
_language_unix_shell_ver=0.40.1
_language_vala_modern_ver=0.3.2
pkgname=${_pkgname}-editor-${_version}
pkgver=1.14.0.dev.i1.18.3.l0.5.1.m0.92.2.p1.0.0.u0.40.1.v0.3.2.c30697
pkgrel=1
pkgdesc='Hackable text editor for the 21st Century, based on web technologies - git channel.'
arch=('x86_64' 'i686')
url="https://github.com/${_pkgname}/${_pkgname}"
license=('MIT')
depends=('alsa-lib' 'gconf' 'gtk2' 'libgnome-keyring' 'libnotify' 'libxtst' 'nodejs-lts-boron' 'nss' 'python2')
optdepends=('gvfs: file deletion support')
makedepends=('git' 'npm')
install=${_pkgname}-${_version}.install
source=("git+${url}.git"
"${_pkgname}-${_version}.desktop"
"${_pkgname}-${_version}")
sha256sums=('SKIP'
'b172e3f81eb42eeb1ad6ef70300c33a79a2015110ea87c413b5857c9694d10e9'
'20d3c386dd60e85977511f9138e32921af051fd7e573d3052822219bd7210be9')
pkgver() {
cd $srcdir/$_pkgname
_basever=$(cat package.json | grep version | sed 's/version//g' | sed 's/://g' | sed 's/ //g' | sed 's/"//g' | sed 's/,//g' | sed 's/-/./g')
_commitno=$(git rev-list --count HEAD)
printf "${_basever}.i${_language_ini_desktop_ver}.l${_language_liquid_ver}.m${_language_gfm2_ver}.p${_language_patch2_ver}.u${_language_unix_shell_ver}.v${_language_vala_modern_ver}.c${_commitno}"
}
prepare() {
cd "$srcdir/${_pkgname}"
sed -i -e "/exception-reporting/d" \
-e "/metrics/d" \
-e "/\"dependencies\": {/a \
\"language-patch2\": \"${_language_patch2_url}\"," \
-e "s/\"language-gfm\": \".*\",/\"language-gfm2\": \"${_language_gfm2_ver}\",\n \"language-ini-desktop\": \"${_language_ini_desktop_ver}\",\n \"language-liquid\": \"${_language_liquid_ver}\",\n \"language-patch2\": \"${_language_patch2_ver}\",/g" \
-e "s/\"language-shellscript\": \".*\",/\"language-unix-shell\": \"${_language_unix_shell_ver}\",\n \"language-vala-modern\": \"${_language_vala_modern_ver}\",/g" \
package.json
chmod 755 -R package.json
sed -i -e 's@node script/bootstrap@node script/bootstrap --no-quiet@g' \
./script/build || die "Fail fixing verbosity of script/build"
sed -i -e "s/<%=Desc=%>/$pkgdesc/g" ${srcdir}/${_pkgname}-${_version}.desktop
}
build() {
cd $srcdir/${_pkgname}
export PYTHON=/usr/bin/python2
until ./script/build; do :; done
}
package() {
cd "$srcdir/${_pkgname}"
_ver=$(cat package.json | grep version | sed 's/version//g' | sed 's/://g' | sed 's/ //g' | sed 's/"//g' | sed 's/,//g')
_commit=$(git rev-parse --short HEAD)
_arch=amd64
if [ "${CARCH}" = "i686" ]; then
_arch=i386
fi
install -dm755 ${pkgdir}/usr/bin
install -dm755 ${pkgdir}/usr/share/${_pkgname}-${_version}
install -dm755 ${pkgdir}/usr/share/applications
install -dm755 ${pkgdir}/usr/share/licenses/$pkgname
install -dm755 ${pkgdir}/usr/share/pixmaps
cp -r out/atom-${_ver}-${_commit}-${_arch}/* ${pkgdir}/usr/share/${_pkgname}-${_version}/
mv ${pkgdir}/usr/share/${_pkgname}-${_version}/atom.png ${pkgdir}/usr/share/pixmaps/${_pkgname}-${_version}.png
mv ${pkgdir}/usr/share/${_pkgname}-${_version}/LICENSE ${pkgdir}/usr/share/licenses/$pkgname/LICENSE
install -Dm755 $srcdir/${_pkgname}-${_version} ${pkgdir}/usr/bin/${_pkgname}-${_version}
install -Dm644 $srcdir/${_pkgname}-${_version}.desktop ${pkgdir}/usr/share/applications/${_pkgname}-${_version}.desktop
rm ${pkgdir}/usr/share/${_pkgname}-${_version}/resources/app/atom.sh
rm -rf ${pkgdir}/usr/share/${_pkgname}-${_version}/resources/app.asar.unpacked/resources
ln -sf "/usr/share/${_pkgname}-${_version}/resources/app/apm/node_modules/.bin/apm" "${pkgdir}/usr/bin/apm-${_version}"
find "$pkgdir" \
-name "*.a" -exec rm '{}' \; \
-or -name "*.bat" -exec rm '{}' \; \
-or -name "benchmark" -prune -exec rm -r '{}' \; \
-or -name "doc" -prune -exec rm -r '{}' \; \
-or -name "html" -prune -exec rm -r '{}' \; \
-or -name "man" -prune -exec rm -r '{}' \; \
-or -path "*/less/gradle" -prune -exec rm -r '{}' \; \
-or -path "*/task-lists/src" -prune -exec rm -r '{}' \; \
-or -name "package.json" -exec sed -i -e "s|${srcdir}/atom/apm|/usr/share/${_pkgname}-${_version}/resources/app/apm|g" '{}' +
}
|