blob: f0caa855bb17b207b7672369d630ae8fed193a8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=atuin-git
pkgver=15.0.0.r0.g9e3fa8b8
pkgrel=1
pkgdesc="Magical shell history (git)"
arch=('x86_64')
url="https://github.com/ellie/atuin"
license=('MIT')
depends=('gcc-libs')
makedepends=('cargo' 'git')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=("git+${url}")
sha256sums=('SKIP')
options=('!lto')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
mkdir completions/
}
build() {
cd "${pkgname%-git}"
cargo build --release --frozen --all-features
for sh in 'bash' 'fish' 'zsh'; do
"target/release/${pkgname%-git}" gen-completions -s "$sh" -o completions/
done
}
check() {
cd "${pkgname%-git}"
cargo test --frozen
}
package() {
cd "${pkgname%-git}"
install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm 644 "completions/${pkgname%-git}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname%-git}"
install -Dm 644 "completions/${pkgname%-git}.fish" -t "${pkgdir}/usr/share/fish/vendor_completions.d"
install -Dm 644 "completions/_${pkgname%-git}" -t "${pkgdir}/usr/share/zsh/site-functions"
}
|