blob: be7b1374931cb31523c9732e98c533fad5b535ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Maintainer: kryksyh <kryksyh@gmail.com>
pkgname=audacity4-nocloud-git
_pkgname=audacity
pkgver=r0
pkgrel=3
pkgdesc="Audacity 4, the next generation of the popular multi-track audio editor (no cloud integration)"
arch=('x86_64')
url="https://github.com/audacity/audacity"
license=('GPL-3.0-or-later')
depends=(
qt6-base
qt6-declarative
qt6-svg
qt6-5compat
expat
libogg
libvorbis
flac
opus
opusfile
lame
mpg123
wavpack
libsndfile
portaudio
sqlite
twolame
libsoxr
soundtouch
libsbsms
lilv
suil
zix
wxwidgets-common
zlib
libpng
freetype2
harfbuzz
pugixml
alsa-lib
hicolor-icon-theme
)
makedepends=(
git
cmake
ninja
python
nasm
qt6-tools
qt6-shadertools
utf8cpp
vulkan-headers
vst3sdk
rapidjson
lv2
)
provides=('audacity4')
conflicts=('audacity4')
source=(
"git+https://github.com/audacity/audacity.git"
"git+https://github.com/musescore/muse_framework.git"
"git+https://github.com/musescore/muse_deps.git"
)
sha256sums=('SKIP' 'SKIP' 'SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | cut -d'.' -f2-
}
prepare() {
cd "$srcdir/$_pkgname"
git submodule init
git config submodule.muse.url "$srcdir/muse_framework"
git config submodule.muse_deps.url "$srcdir/muse_deps"
git -c protocol.file.allow=always submodule update
}
build() {
cd "$srcdir/$_pkgname"
cmake \
-G Ninja \
-S . \
-B build \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_INSTALL_PREFIX=/usr \
-D EXTDEPS_OVERRIDE_ALL=SYSTEM \
-D WX_CONFIG=/usr/bin/wx-config-base \
-D MUSE_APP_INSTALL_SUFFIX=4 \
-D MUSE_ENABLE_UNIT_TESTS=OFF \
-D MUSE_MODULE_DIAGNOSTICS_CRASHPAD_CLIENT=OFF \
-D MUSE_MODULE_UPDATE=OFF \
-D AU4_BUILD_MODE=release \
-D AU_BUILD_CLOUD_AUDIOCOM=OFF \
-D AU_BUILD_USAGEINFO_MODULE=OFF
cmake --build build
}
package() {
cd "$srcdir/$_pkgname"
DESTDIR="$pkgdir" cmake --install build
}
|