blob: 2fa4e9b6562f7991fe8e3e44dc1742fe56b6099f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Philip Goto <philip.goto@gmail.com>
pkgname=audio-sharing
pkgver=0.2.2
pkgrel=1
pkgdesc="Share your computer audio"
arch=('x86_64' 'aarch64')
url="https://apps.gnome.org/AudioSharing"
license=('GPL3')
depends=('gst-rtsp-server' 'libadwaita')
makedepends=('cargo' 'git' 'meson')
checkdepends=('appstream-glib')
source=("https://gitlab.gnome.org/World/AudioSharing/-/archive/$pkgver/AudioSharing-$pkgver.tar.gz")
sha256sums=('baebdefb33329b81a9f5aa68f4b906453625256e90e0df963ed164220a71cb1a')
prepare() {
cd "AudioSharing-$pkgver"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --target "$CARCH-unknown-linux-gnu"
}
build() {
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
arch-meson "AudioSharing-$pkgver" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|