blob: db42fb8ab2478e041cc286c44a6d603531e421b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Simon Legner <Simon.Legner@gmail.com>
pkgname=aur-out-of-date
pkgver=1.0.0
pkgrel=1
pkgdesc="Determines out-of-date AUR packages"
arch=('x86_64' 'i686')
url="https://github.com/simon04/aur-out-of-date"
license=('GPL')
source=("https://github.com/simon04/$pkgname/archive/v$pkgver.tar.gz")
makedepends=('go' 'dep' 'git')
_importpath="github.com/simon04/$pkgname"
prepare() {
export GOPATH="$srcdir/_go"
mkdir -p $(dirname "$GOPATH/src/$_importpath")
ln -sf "$srcdir/$pkgname-$pkgver" "$GOPATH/src/$_importpath"
cd "$GOPATH/src/$_importpath"
dep ensure
}
check() {
export GOPATH="$srcdir/_go"
cd "$GOPATH/src/$_importpath"
go test $(go list ./...)
}
build() {
export GOPATH="$srcdir/_go"
cd "$GOPATH/src/$_importpath"
go build
}
package() {
export GOPATH="$srcdir/_go"
cd "$GOPATH/src/$_importpath"
install -dm755 "$pkgdir/usr/bin"
install -m755 "$pkgname" "$pkgdir/usr/bin/aur-out-of-date"
}
sha256sums=('8da66eeaa7fc5759d8768d91914d741c5ab1df0b8aca7599d880921df8286e58')
|