PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Stephan Springer <buzo+arch@Lini.de>

_pkgname=aurblobs
pkgname="$_pkgname-git"
pkgver=r80.2dfcc20
pkgrel=1
pkgdesc='Automatically build AUR packages and serve them from a repository (git version)'
arch=('any')
url='https://github.com/aurblobs/aurblobs'
license=('AGPL3')
makedepends=('git' 'python-setuptools')
depends=('python-click' 'python-docker' 'python-gitpython' 'git'
         'python-pretty_bad_protocol' 'python-xdg')
source=("git+https://github.com/$_pkgname/$_pkgname.git"
       'fix-constants.diff')
sha256sums=('SKIP' 'SKIP')

pkgver() {
    cd "$_pkgname/"
    printf "r%s.%s" \
           "$(git rev-list --count HEAD)" \
           "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$_pkgname/"
    patch -p2 -i "$srcdir"/fix-constants.diff
}

build() {
    cd "$_pkgname"
    python setup.py build
}

package() {
    cd "$_pkgname"
    python setup.py install --root="$pkgdir" --optimize=1
}